bundle agent ldapclient
{
# Configure NSS and PAM to use LDAP directory

commands:

  debian.roaming.installation::

    "/usr/share/debian-edu-config/tools/setup-roaming"
      contain => in_shell;

# remove PAM LDAP module
  debian.!roaming.installation::

    "/usr/sbin/pam-auth-update --disable ldap"
      contain => in_shell;
}

bundle agent editline_ldapclient
{
# Configure Debian Edu specific setup.

vars:

  "nss_conf"   slist  => { "passwd:         files ldap",
                           "group:          files ldap",
                           "shadow:         files ldap",
                           "netgroup:       nis   ldap",
                           "automount:      files ldap" };

files:

  debian.!standalone.!roaming.installation::

    "/etc/sudo-ldap.conf"
    link_from => ln_s("/usr/share/debian-edu-config/sudo-ldap.conf"),
    move_obstructions => "true";

    "/etc/nsswitch.conf"
      edit_line => append_if_no_line( @(nss_conf) );

    "/etc/nsswitch.conf"
      edit_line => nsswitch_conf;
}

bundle edit_line nsswitch_conf
{

vars:

  "regexpr" slist => { "passwd:         files", "group:          files",
                       "shadow:         files", "netgroup:       nis" };

replace_patterns:

  "^($(regexpr))$" replace_with => comment("#");
}